Supplementary Text 2 - Codes for Diabetes Disease Mapping Model

// Disease mapping was ran by software package Stan via the RStan library (http://mc-stan.org/).

// Areal disease risk estimation model with random effects specified as the covolution of

// spatial and non-spatial random effect, as proposed by Riebler et al. 2019

// See reference in the main text and link below

// https://mc-stan.org/users/documentation/case-studies/icar\_stan.html

// Declaration of data

data {

 int<lower=0> N; // number of areas

 int<lower=0> N\_edges; //Spatial information: number of graph edges for areas

 int<lower=1, upper=N> node1[N\_edges]; // node1[i] adjacent to node2[i]

 int<lower=1, upper=N> node2[N\_edges]; // and node1[i] < node2[i]

 vector<lower=0>[N] E; // expected count of diabetes

 int<lower=0> Y[N]; // outcome, count of diabetes for area

 vector[N] EDUC; // covariates: education

 vector[N] IMMIG; // covariates: immigrant

 vector[N] INCOME; // covariates: income

 vector[N] RECFACILITY; // covariates: recreational facility

 vector[N] YOGFL; // indicator for flavoured yogurt

 vector[N] YOGPL; // indicator for plain yogurt

 vector[N] CSD; // indicator for soda – no diet soda added due to correlation with soda

 real<lower=0> scaling\_factor; // scales the variance of the spatial effects

 real<lower=0> betaPrior; // scaling parameter for the prior of regression coefficients, passed from R stan

}

transformed data {

 vector[N] log\_E = log(E); //expected count of diabetes

}

//Parameters to estimate

parameters {

 real beta0;

 real gammaEduc; //covariate: education

 real gammaImmig; //covariate: immigrants

 real gammaIncome; //covariate: income

 real gammaRecFacility; //covariate: recreational facility availablility

 real betaSaleYogFl;

 real betaSaleYogPl;

 real betaSaleCsd;

 real<lower=0> sigma; // Overall standard deviation

 real<lower=0, upper=1> rho; // Mixing parameter: proportion unstructured vs. spatially structured variance

 vector[N] u; // Heterogeneous (non-spatial) random effects

 vector[N] nu; // Spatial random effects

}

transformed parameters {

 vector[N] convolved\_re;

 // specification of the convolution random effect, b\_i in the main text

 // variance of each component should be approximately equal to 1

 convolved\_re = sqrt(1 - rho) \* u + sqrt(rho / scaling\_factor) \* nu;

}

model {

 // Mean function for disease count, with expected disease count as offset

 Y ~ poisson\_log(log\_E + beta0 +

 gammaEduc\*EDUC +

 gammaImmig\*IMMIG +

 gammaIncome\*INCOME +

 gammaRecFacility\*RECFACILITY +

 betaSaleCsd\*CSD+

 betaSaleYogFl\*YOGFL +

 betaSaleYogPl\*YOGPL +

 convolved\_re\*sigma);

 // Prior for nu, the spatial effect

 target += -0.5 \* dot\_self(nu[node1] - nu[node2]);

 // Soft iCAR sum-to-zero constraint on nu)

 sum(nu) ~ normal(0, 0.001 \* N); // equivalent to mean(nu) ~ normal(0,0.001)

 // Priors for regression coefficients

 beta0 ~ normal(0, betaPrior);

 gammaEduc ~ normal(0, betaPrior);

 gammaImmig ~ normal(0, betaPrior);

 gammaIncome ~ normal(0, betaPrior);

 gammaRecFacility ~ normal(0, betaPrior);

 betaSaleCsd ~ normal(0,betaPrior);

 betaSaleYogFl ~ normal(0,betaPrior);

 betaSaleYogPl ~ normal(0,betaPrior);

 // Priors for BYM parameters

 u ~ normal(0.0, 1.0);

 sigma ~ normal(0,5);

 rho ~ uniform(0, 1);

} // End of file for diabetes model