**Supplementary material for**

**Longitudinal pathways between emotional difficulties and school absenteeism in middle childhood: Evidence from developmental cascades**

**Syntax: Random-intercept panel model for unauthorized absence in Mplus**

data: file = attend\_implist.dat;

type=imputation;

variable:

names = sc\_id ethnic sen fsm uab1 uab2 uab3 emo1\_t1-emo5\_t3

age ks1 hyper1 peer1 sch1 hyper2 peer2 sch2 hyper3 peer3 sch3;

usevariables = ethnic sen fsm uab1 uab2 uab3 emo1\_t1-emo5\_t3

age ks1 hyper1 peer1 sch1 hyper2 peer2 sch2 hyper3 peer3 sch3;

categorical = emo1\_t1-emo5\_t3;

missing = \*;

cluster = sc\_id;

define:

ks1=ks1/10; !rescaling the variance of variables to avoid convergence issues

uab1=uab1/10;

uab2=uab2/10;

uab3=uab3/10;

analysis:

type = complex;

estimator = wlsmv;

parameterization = theta;

model = nocov;

model:

!latent variables (loadings held equal across time)

emo1 by emo1\_t1 (l1)

emo2\_t1 (l2)

emo3\_t1 (l3)

emo4\_t1 (l4)

emo5\_t1 (l5);

emo2 by emo1\_t2 (l1)

emo2\_t2 (l2)

emo3\_t2 (l3)

emo4\_t2 (l4)

emo5\_t2 (l5);

emo3 by emo1\_t3 (l1)

emo2\_t3 (l2)

emo3\_t3 (l3)

emo4\_t3 (l4)

emo5\_t3 (l5);

!residual covariances

emo1\_t1 with emo1\_t2 emo1\_t3;

emo1\_t2 with emo1\_t3;

emo2\_t1 with emo2\_t2 emo2\_t3;

emo2\_t2 with emo2\_t3;

emo3\_t1 with emo3\_t2 emo3\_t3;

emo3\_t2 with emo3\_t3;

emo4\_t1 with emo4\_t2 emo4\_t3;

emo5\_t2 with emo4\_t3;

emo5\_t1 with emo5\_t2 emo5\_t3;

emo5\_t2 with emo5\_t3;

!equal thresholds

[emo1\_t1$1] (t11);

[emo2\_t1$1] (t21);

[emo3\_t1$1] (t31);

[emo4\_t1$1] (t41);

[emo5\_t1$1] (t51);

[emo1\_t1$2] (t12);

[emo2\_t1$2] (t22);

[emo3\_t1$2] (t32);

[emo4\_t1$2] (t42);

[emo5\_t1$2] (t52);

[emo1\_t2$1] (t11);

[emo2\_t2$1] (t21);

[emo3\_t2$1] (t31);

[emo4\_t2$1] (t41);

[emo5\_t2$1] (t51);

[emo1\_t2$2] (t12);

[emo2\_t2$2] (t22);

[emo3\_t2$2] (t32);

[emo4\_t2$2] (t42);

[emo5\_t2$2] (t52);

[emo1\_t3$1] (t11);

[emo2\_t3$1] (t21);

[emo3\_t3$1] (t31);

[emo4\_t3$1] (t41);

[emo5\_t3$1] (t51);

[emo1\_t3$2] (t12);

[emo2\_t3$2] (t22);

[emo3\_t3$2] (t32);

[emo4\_t3$2] (t42);

[emo5\_t3$2] (t52);

[emo2\* emo3\*];

!covariates

!time-invariant covariates held equal across time

emo1-emo3 on ethnic (c1);

emo1-emo3 on fsm (c2);

emo1-emo3 on sen (c3);

uab1-uab3 on ethnic (c6);

uab1-uab3 on fsm (c7);

uab1-uab3 on sen (c8);

!covariates at baseline only

emo1 on ks1 age;

uab1 on ks1 age;

!time-varying covariates

emo1 on hyper1 peer1 sch1

emo2 on hyper2 peer2 sch2;

emo3 on hyper3 peer3 sch3;

uab1 on hyper1 peer1 sch1;

uab2 on hyper2 peer2 sch2;

uab3 on hyper3 peer3 sch3;

!random intercepts

riemo by emo1@1 emo2@1 emo3@1;

riab by uab1@1 uab2@1 uab3@1;

!residual variances to zero

emo1-emo3@0;

uab1-uab3@0;

!within part

wemo1 by emo1@1;

wemo2 by emo2@1;

wemo3 by emo3@1;

wab1 by uab1@1;

wab2 by uab2@1;

wab3 by uab3@1;

!random intercepts correlated

riemo with riab;

!cross-lagged and stability

wemo3 on wemo2 wab2;

wab3 on wemo2 wab2;

wemo2 on wemo1 wab1;

wab2 on wemo1 wab1;

!within time

wemo3 with wab3;

wemo2 with wab2;

wemo1 with wab1;

output: sampstat stand tech1 mod cinterval;

**Syntax**: Exploring the equality of paths using Wald Test between genders

!syntax is the same as above, except for the following differences:

variable:

!add this

grouping = gender (0 = male 1 = female);

model:

!implement the following changes

!random intercepts correlates

riemo with riab (pm1);

!cross-lagged and stability

wemo3 on wemo2 (pm2);

wemo3 on wab2 (pm3);

wab3 on wemo2 (pm4);

wab3 on wab2 (pm5);

wemo2 on wemo1 (pm6);

wemo2 on wab1 (pm7);

wab2 on wemo1 (pm8);

wab2 on wab1 (pm9);

!within time

wemo3 with wab3 (pm10);

wemo2 with wab2 (pm11);

wemo1 with wab1 (pm12);

model female:

[wemo1-wab3@0];

[riemo@0];

[riab@0];

riemo with riab(pf1);

wemo3 on wemo2 (pf2);

wemo3 on wab2 (pf3);

wab3 on wemo2 (pf4);

wab3 on wab2 (pf5);

wemo2 on wemo1 (pf6);

wemo2 on wab1 (pf7);

wab2 on wemo1 (pf8);

wab2 on wab1 (pf9);

wemo3 with wab3 (pf10);

wemo2 with wab2 (pf11);

wemo1 with wab1 (pf12);

model test:

0 = pm1-pf1;

0 = pm2-pf2;

0 = pm3-pf3;

0 = pm4-pf4;

0 = pm5-pf5;

0 = pm6-pf6;

0 = pm7-pf7;

0 = pm8-pf8;

0 = pm9-pf9;

0 = pm9-pf10;

0 = pm9-pf11;

0 = pm9-pf12;

**Syntax**: Time measurement invariance for emotional latent variable

This is the configural model

analysis:

type = complex;

estimator = wlsmv;

parameterization = theta;

model:

!free loadings

emo1 by emo1\_t1\* emo2\_t1 emo3\_t1 emo4\_t1 emo5\_t1;

emo2 by emo1\_t2\* emo2\_t2 emo3\_t2 emo4\_t2 emo5\_t2;

emo3 by emo1\_t3\* emo2\_t3 emo3\_t3 emo4\_t3 emo5\_t3;

!residual covariances

emo1\_t1 with emo1\_t2 emo1\_t3; emo1\_t2 with emo1\_t3;

emo2\_t1 with emo2\_t2 emo2\_t3; emo2\_t2 with emo2\_t3;

emo3\_t1 with emo3\_t2 emo3\_t3; emo3\_t2 with emo3\_t3;

emo4\_t1 with emo4\_t2 emo4\_t3; emo5\_t2 with emo4\_t3;

emo5\_t1 with emo5\_t2 emo5\_t3; emo5\_t2 with emo5\_t3;

!fixed residuals at all time points

emo1\_t1-emo5\_t3@1;

emo1-emo3@1;

!free thresholds

[emo1\_t1$1-emo5\_t3$1];

[emo1\_t1$1-emo5\_t3$1];

!fixed means at all time points

[emo1-emo3@0];

output: sampstat stand tech1 mod;

savedata: difftest = longConf.dat;

**Syntax**: Time measurement invariance for emotional latent variable

This is the scalar model (loadings and thresholds held equal in tandem)

analysis:

type = complex;

estimator = wlsmv;

parameterization = theta;

difftest = longConf.dat; !this compares the nested models

model:

!equal loadings

emo1 by emo1\_t1-emo5\_t1\* (l1-l5);

emo2 by emo1\_t2-emo5\_t2\* (l1-l5);

emo3 by emo1\_t3-emo5\_t3\* (l1-l5);

!residual covariances

emo1\_t1 with emo1\_t2 emo1\_t3; emo1\_t2 with emo1\_t3;

emo2\_t1 with emo2\_t2 emo2\_t3; emo2\_t2 with emo2\_t3;

emo3\_t1 with emo3\_t2 emo3\_t3; emo3\_t2 with emo3\_t3;

emo4\_t1 with emo4\_t2 emo4\_t3; emo5\_t2 with emo4\_t3;

emo5\_t1 with emo5\_t2 emo5\_t3; emo5\_t2 with emo5\_t3;

!fixed residuals at T1 and free at T2 and T3

emo1\_t1-emo5\_t1@1;

emo1\_t2-emo5\_t3\*;

emo1-emo3@1;

!equal thresholds

[emo1\_t1$1-emo5\_t1$1] (t1-t5);

[emo1\_t2$1-emo5\_t2$1] (t1-t5);

[emo1\_t3$1-emo5\_t3$1] (t1-t5);

[emo1\_t1$2-emo5\_t1$2] (t6-t10);

[emo1\_t2$2-emo5\_t2$2] (t6-t10);

[emo1\_t3$2-emo5\_t3$2] (t6-t10);

!fixed mean at T1 and free at T2-T3

[emo1@0];

[emo2-emo3\*];

Table S1. Gender and longitudinal measurement invariance for SDQ-emotional difficulties

|  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- |
|  | χ2 (df) | CFI | TLI | RMSEA [90%] | SRMR | λ | Δχ2 (df) |
| Group measurement invariance |  |  |  |  |  |  |  |
| Baseline Boys | 107.45 (72)\*\* | .99 | .99 | .02 [.01, .03] | .05 | T1: .55–.86, T2: 52–.89, T3: 56–.94 |  |
| Baseline Girls | 27.68 (22)\*\* | .99 | .98 | .02 [.02, .03] | .04 | T1: .57–.87, T2: 63–.90, T3: 59–.91 |  |
| Configural | 224.11 (144)\*\*\* | .99 | .99 | .02 [.02, .03] | .05 |  |  |
| Scalar | 245.45 (166)\*\*\* | .99 | .99 | .02 [.02, .02] | .05 |  | 27.68 (22), p = .19 |
| Longitudinal full sample |  |  |  |  |  |  |  |
| Baseline Time 1 | 62.41 (5)\*\*\* | .99 | .97 | .07 [.06, .09] | .03 | .56–.86 |  |
| Baseline Time 2 | 74.09 (5)\*\*\* | .97 | .95 | .09 [.07, .11] | .04 | .60–.90 |  |
| Baseline Time 3 | 56.65 (5)\*\*\* | .99 | .98 | .09 [.07, .11] | .05 | .59–.90 |  |
| Configural | 144.96 (72)\*\*\* | .99 | .99 | .02 [.02, .03] | .04 |  |  |
| Scalar | 163.45 (90)\*\*\* | .99 | .99 | .02 [.01, .02] | .04 |  | 24.75 (18), p = .13 |

Table S2. Standardised covariate effects on authorised absence x emotional symptoms model for girls/boys

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
|  | Emotional symptoms | | | Authorised absence | | |
| Covariates | Time1 | Time2 | Time3 | Time1 | Time2 | Time3 |
| **Time 1** |  |  |  |  |  |  |
| Attainment | -.08/-.06 |  |  | **-.12\*\*\*/-.13\*\*** |  |  |
| Age | -.02/-.04 |  |  | -.05/-.02 |  |  |
| **Time-varying (T1-T3)** |  |  |  |  |  |  |
| Hyperactivity | **.20\*\*\*/.19\*\*** | **.17\*\*/.22\*\*\*** | **.20\*\*\*/.24\*\*\*** | .01/-.02 | -.00/.08 | .01/-.01 |
| Peer problems | **.29\*\*\*/.29\*\*\*** | **.37\*\*\*/.36\*\*\*** | **.40\*\*\*/.41\*\*\*** | -.01/-.00 | .08/-.01 | .01/.01 |
| School connectedness | -.08/-.05 | -.05/-.03 | -.04/-.02 | .01/-.01 | -.07/-.05 | -.03**/-.11\*\*** |
| **Time-invariant** |  |  |  |  |  |  |
| Ethnicity (1 = UK ethnic minority) | **-.19\*/-.18\*\*** | | | **-.24\***/-.09 | | |
| FSM (1 = yes) | .06/.06 | | | **.14\*\*/.23\*\*\*** | | |
| SEN (1 = yes) | .16/.14 | | | .10/.05 | | |

Table S3. Standardised covariate effects on unauthorised absence x emotional symptoms model for the whole sample

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
|  | Emotional symptoms | | | Unauthorised absence | | |
| Covariates | Time1 | Time2 | Time3 | Time1 | Time2 | Time3 |
| **Time 1** |  |  |  |  |  |  |
| Attainment | -.06 |  |  | **-.16\*\*\*** |  |  |
| Age | -.03 |  |  | -.00 |  |  |
| **Time-varying (T1-T3)** |  |  |  |  |  |  |
| Hyperactivity | **.19\*\*\*** | **.18\*\*\*** | **.22\*\*\*** | -.01 | .04 | .00 |
| Peer problems | **.30\*\*\*** | **.38\*\*\*** | **.40\*\*\*** | -.00 | .00 | -.01 |
| School connectedness | **-.05\*** | -.03 | -.02 | -.03 | -.06 | .00 |
| **Time-invariant** |  |  |  |  |  |  |
| Ethnicity (1 = UK ethnic minority) | **-.19\*\*\*** | | | -.07 | | |
| FSM (1 = yes) | .06 | | | **.37\*\*\*** | | |
| SEN (1 = yes) | **.13\*** | | | -.02 | | |