**CHRONOLOGY OF A FORTIFIED MISSISSIPPIAN VILLAGE IN THE CENTRAL ILLINOIS RIVER VALLEY**

Anthony M. Krus, Edward W. Herrmann, Matthew D. Pike, G. William Monaghan, Jeremy J. Wilson

**ONLINE SUPPLEMENT**

*Sensitivity Analysis*

An alternative Bayesian model was created to account for the possiblity that five of the measurements modeled as *TPQ* in the primary model may actually date the formation or use of their associated contexts (UCIAMS-164693, UCIAMS-164696, UCIAMS-164697, UCIAMS-145761, UCIAMS-145762). These five samples were selected for 14C dating with the assumption that they securely date their context and, while this may not necessarily be the case, this possibility is explored in an alternative model as a sensitivity analysis.

The structure of the alternative model is nearly identical to the primary model; the only difference is that five dates are modeled as being reflective of the timing of their contexts instead of being modeled as *TPQ*. The algorithm used for the alternative model can be directly derived from the model structure shown in Online Supplement Figure 1. The alternative model shows good overall agreement (Amodel=91.7) between the 14C dates and the model assumptions. The model estimates that the earliest activity on the site began in *cal AD 1030–1160* (*95% probability*; Online Supplement Figure 1; *Alternative Model 1: Start Lawrenz*), and probably in *cal AD 1090–1150* (*68% probability*). The model estimates that palisade construction began in *cal AD 1150–1210* (*95% probability*; Online Supplement Figure 1; *Alternative Model 1: Start Circular Bastion Palisade*), and probably in *cal AD 1160–1190* (*68% probability*). Palisade modifications and repair are estimated to have continued for the next *35–120 yr* (*95% probability*; Figure 4; *Alternative Model 1: Palisade Span*), and probably for *55–95 yr* (*68% probability*). The model estimates construction of the palisade with rectangular bastions began in *cal AD 1190–1245* (*95% probability*; Online Supplement Figure 1; *Alternative Model 1: Start Rectangular Bastion Palisade*), and probably in *cal AD 1205–1230* (*68% probability*). Palisade modifications and repair are estimated to have ended in *cal AD 1220–1290* (*95% probability*; Online Supplement Figure 1; *Alternative Model 1: End Lawrenz palisade*), and probably in *cal AD 1235–1265* (*68% probability*). Activity on the site is estimated to have ended in *cal AD 1295–1405* (*95% probability*; Online Supplement Figure 1; *Alternative Model 1: End Lawrenz*), probably in *cal AD 1300–1340* (*68% probability*), spanning *145–340 yr* (*95% probability*; Figure 4; *Alternative Model 1: Lawrenz span*), probably for *160–245 yr* (*68% probability*).

A second alternative Bayesian model was created to model only the measurements related to the palisade as a sensitivity analysis to assess how the measurements from non-palisade contexts influence the posterior probabilities related to palisade construction and modification in the primary model and first alternative model. The 14C dates from palisade contexts (UCIAMS-164697, UCIAMS-164695, UCIAMS-164699, UCIAMS-164700, UCIAMS-145761, UCIAMS-145762, UCIAMS-145763) were modeled with the prior assumption that they are representative of a single, relatively uniform phase of activity. Boundaries were placed around this sequence in OxCal to estimate a start and end date. Sequences were created in this phase to reflect the stratigraphic ordering of the 14C samples (Figure 2 and Online Supplement Figure 2). Measurements related to the palisade modeled as *TPQ* in the primary model are also modeled as *TPQ* in this second alternative model (UCIAMS-164697, UCIAMS-145761, UCIAMS-145762). Like the primary and first alternative models, the Charcoal Outlier Model was adopted as a strategy for accounting for the unknown in-built age offset in wood charcoal samples to create a more accurate and robust model and follows the same assumptions as the Charcoal Outlier Model used in the primary model. Non-charcoal 14C measurements were given a prior probability of 5% of being statistical outliers, using the General Outlier Model.

The algorithm used for the second alternative model can be directly derived from the model structure shown in Online Supplement Figure 2. The second alternative model shows good overall agreement (Amodel=84.5) between the 14C dates and the model assumptions. The model estimates that palisade construction began in *cal AD 1125–1250* (*95% probability*; Online Supplement Figure 2; *Alternative Model 2: Start Palisade*), and probably in *cal AD 1170–1220* (*68% probability*). Palisade modifications and repair are estimated to have continued for the next *1–165 yr* (*95% probability*; Figure 4; *Alternative Model 2: Palisade Span*), and probably for *10–90 yr* (*68% probability*). The model estimates construction of the palisade with rectangular bastions began in *cal AD 1205–1260* (*95% probability*; Online Supplement Figure 2; *Alternative Model 2: Start Rectangular Bastion Palisade*), and probably in *cal AD 1215–1245* (*68% probability*). Palisade modifications and repair are estimated to have ended in *cal AD 1210–1315* (*95% probability*; Online Supplement Figure 2; *Alternative Model 2: End Palisade*), and probably in *cal AD 1225–1270* (*68% probability*).

****

Online Supplement Figure 1: Results and structure of the first alternative model. The brackets and keywords define the model structure. The format is as described in Figure 3.

****

Online Supplement Figure 2: Results and structure of the second alternative model. The brackets and keywords define the model structure. The format is as described in Figure 3.

**Online Supplement Table 1. Posterior probabilities from the Bayesian models for the estimated start and end dates for the settlement and palisade.**

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| Event Dated | Primary Model (*95.4% probability)* | Primary Model (*68.2% probability)* | Alternative Model 1 (*95.4% probability)* | Alternative Model 1 (*68.2% probability)* | Alternative Model 2 (*95.4% probability)* | Alternative Model 2 (*68.2% probability)* |
| Start of Lawrenz |  *990–1165* |  *1075–1150* |  *1035–1160* |  *1090–1150* | n/a | n/a |
| Construction of palisade with circular bastions |  *1150–1230* |  *1165–1205* |  *1150–1210* |  *1160–1190* |  *1125–1250* |  *1170–1220* |
| Construction of palisade with rectangular bastions |  *1200–1260* |  *1210–1250* |  *1190–1245* |  *1205–1230* |  *1205–1260* |  *1215–1245* |
| End of palisade use |  *1215–1305* |  *1230–1265* |  *1220–1290* |  *1235–1265* |  *1210–1315* |  *1225–1270* |
| End of Lawrenz | *1295–1450* | *1300–1405* |  *1295–1405* |  *1300–1340* | n/a | n/a |

*Note:* All dates are in *cal AD*.

**Online Supplement Table 2. Posterior probabilities from the Bayesian models for the estimated spans for the settlement and palisade chronologies.**

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| Event Dated | Primary Model(*95.4% probability)* | Primary Model(*68.2% probability)* | Alternative Model 1(*95.4% probability)* | Alternative Model 1(*68.2% probability)* | Alternative Model 2(*95.4% probability)* | Alternative Model 2(*68.2% probability)* |
| Length of Lawrenz occupation | *150–420* | *175–310* | *145–335* | *160–245* | n/a | n/a |
| Palisade use life | *15–125* | *40–85* | *35–120* | *55–95* | *1–165* | *10–90* |

*Note:* All dates are in *yrs*.

*OxCal code used for Bayesian modeling.*

Primary model:

Plot()

 {

 Outlier\_Model("Charcoal",Exp(1,-10,0),U(0,3),"t");

 Outlier\_Model("General",T(5),U(0,4),"t");

 Sequence()

 {

 Boundary("Primary Model: Start Lawrenz");

 Phase()

 {

 R\_Date("north structure floor: UCIAMS-169486", 940, 15)

 {

 Outlier("Charcoal", 1);

 };

 After("south house wall trench")

 {

 R\_Date("UCIAMS-164693", 935, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 After("sub-mound structure (core)")

 {

 R\_Date("UCIAMS-164696", 850, 20)

 {

 Outlier("General", 0.05);

 };

 };

 R\_Date("UCIAMS-164698: structural thatch", 925, 20)

 {

 Outlier("General", 0.05);

 };

 R\_Date("Beta-281698: structural thatch", 690, 40)

 {

 Outlier("General", 0.05);

 };

 Phase("burnt structure")

 {

 R\_Date("UCIAMS-145759: burnt thatch", 665, 20)

 {

 Outlier("General", 0.05);

 };

 R\_Date("UCIAMS-145760: burnt timber", 640, 20)

 {

 Outlier("General", 0.05);

 };

 };

 R\_Date("UCIAMS-153692: storage pit", 625, 20)

 {

 Outlier("General", 0.05);

 };

 Phase("palisades")

 {

 Sequence()

 {

 Phase("circular bastion palisade")

 {

 First("Primary Model: Start Circular Bastion Palisade");

 Sequence()

 {

 After("older south bastion trench")

 {

 R\_Date("UCIAMS-164697", 830, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 R\_Date("UCIAMS-164695: south bastion possible ph", 840, 20)

 {

 Outlier("Charcoal", 1);

 };

 R\_Date("UCIAMS-164699: wall/bastion collapse", 830, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 Sequence()

 {

 After("deposit cut by circular bastion")

 {

 R\_Date("UCIAMS-164709", 890, 20)

 {

 Outlier("General", 0.05);

 };

 };

 Phase("north palisade wall")

 {

 R\_Date("UCIAMS-164700: north palisade wall", 875, 20)

 {

 Outlier("Charcoal", 1);

 };

 After("north palisade wall (duck)")

 {

 R\_Date("UCIAMS-164708", 1135, 20)

 {

 Outlier();

 };

 };

 };

 };

 };

 Phase("rectangular bastion palisade")

 {

 First("Primary Model: Start Rectangular Bastion Palisade");

 Phase("rectangular bastion")

 {

 After("rectangular bastion post-mold")

 {

 R\_Date("UCIAMS-145761", 810, 20)

 {

 Outlier("General", 0.05);

 };

 R\_Date("UCIAMS-145762", 840, 20)

 {

 Outlier("General", 0.05);

 };

 };

 R\_Date("UCIAMS-145763: base of rectangular bastion trench", 805, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 R\_Date("UCIAMS-164694: burned area", 845, 20)

 {

 Outlier("General", 0.05);

 };

 Last("Primary Model: End Rectangular Bastion Palisade");

 };

 };

 };

 };

 Boundary("Primary Model: End Lawrenz");

 Difference("Primary Model: Palisade Span", "Primary Model: End Rectangular Bastion Palisade", "Primary Model: Start Circular Bastion Palisade");

 Difference("Primary Model: Lawrenz Span", "Primary Model: End Lawrenz", "Primary Model: Start Lawrenz");

 };

 };

First alternative model:

Plot()

 {

 Outlier\_Model("Charcoal",Exp(1,-10,0),U(0,3),"t");

 Outlier\_Model("General",T(5),U(0,4),"t");

 Sequence()

 {

 Boundary("Alternative Model 1: Start Lawrenz");

 Phase()

 {

 R\_Date("north structure floor: UCIAMS-169486", 940, 15)

 {

 Outlier("Charcoal", 1);

 };

 R\_Date("south house wall trench: UCIAMS-164693", 935, 20)

 {

 Outlier("Charcoal", 1);

 };

 R\_Date("sub-mound structure (core): UCIAMS-164696", 850, 20)

 {

 Outlier("General", 0.05);

 };

 R\_Date("UCIAMS-164698: structural thatch", 925, 20)

 {

 Outlier("General", 0.05);

 };

 R\_Date("Beta-281698: structural thatch", 690, 40)

 {

 Outlier("General", 0.05);

 };

 Phase("burnt structure")

 {

 R\_Date("UCIAMS-145759: burnt thatch", 665, 20)

 {

 Outlier("General", 0.05);

 };

 R\_Date("UCIAMS-145760: burnt timber", 640, 20)

 {

 Outlier("General", 0.05);

 };

 };

 R\_Date("UCIAMS-153692: storage pit", 625, 20)

 {

 Outlier("General", 0.05);

 };

 Phase("palisades")

 {

 Sequence()

 {

 Phase("circular bastion palisade")

 {

 First("Alternative Model 1: Start Circular Bastion Palisade");

 Sequence()

 {

 R\_Date("older south bastion trench: UCIAMS-164697", 830, 20)

 {

 Outlier("Charcoal", 1);

 };

 R\_Date("UCIAMS-164695: south bastion possible ph", 840, 20)

 {

 Outlier("Charcoal", 1);

 };

 R\_Date("UCIAMS-164699: wall/bastion collapse", 830, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 Sequence()

 {

 After("deposit cut by circular bastion")

 {

 R\_Date("UCIAMS-164709", 890, 20)

 {

 Outlier("General", 0.05);

 };

 };

 Phase("north palisade wall")

 {

 R\_Date("UCIAMS-164700: north palisade wall", 875, 20)

 {

 Outlier("Charcoal", 1);

 };

 After("north palisade wall (duck)")

 {

 R\_Date("UCIAMS-164708", 1135, 20)

 {

 Outlier();

 };

 };

 };

 };

 };

 Phase("rectangular bastion palisade")

 {

 First("Alternative Model 1: Start Rectangular Bastion Palisade");

 Phase("rectangular bastion")

 {

 Phase("rectangular bastion post-mold")

 {

 R\_Date("UCIAMS-145761", 810, 20)

 {

 Outlier("General", 0.05);

 };

 R\_Date("UCIAMS-145762", 840, 20)

 {

 Outlier("General", 0.05);

 };

 };

 R\_Date("UCIAMS-145763: base of rectangular bastion trench", 805, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 R\_Date("UCIAMS-164694: burned area", 845, 20)

 {

 Outlier("General", 0.05);

 };

 Last("Alternative Model 1: End Rectangular Bastion Palisade");

 };

 };

 };

 };

 Boundary("Alternative Model 1: End Lawrenz");

 Difference("Alternative Model 1: Palisade Span", "Alternative Model 1: End Rectangular Bastion Palisade", "Alternative Model 1: Start Circular Bastion Palisade");

 Difference("Alternative Model 1: Lawrenz Span", "Alternative Model 1: End Lawrenz", "Alternative Model 1: Start Lawrenz");

 };

 };

Second alternative model:

Plot()

 {

 Outlier\_Model("Charcoal",Exp(1,-10,0),U(0,3),"t");

 Outlier\_Model("General",T(5),U(0,4),"t");

 Sequence()

 {

 Boundary("Alternative Model 2: Start Palisade");

 Phase("palisades")

 {

 Sequence()

 {

 Phase("circular bastion palisade")

 {

 Sequence()

 {

 After("older south bastion trench")

 {

 R\_Date("UCIAMS-164697", 830, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 R\_Date("UCIAMS-164695: south bastion possible ph", 840, 20)

 {

 Outlier("Charcoal", 1);

 };

 R\_Date("UCIAMS-164699: wall/bastion collapse", 830, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 Sequence()

 {

 After("deposit cut by circular bastion")

 {

 R\_Date("UCIAMS-164709", 890, 20)

 {

 Outlier("General", 0.05);

 };

 };

 Phase("north palisade wall")

 {

 R\_Date("UCIAMS-164700: north palisade wall", 875, 20)

 {

 Outlier("Charcoal", 1);

 };

 After("north palisade wall (duck)")

 {

 R\_Date("UCIAMS-164708", 1135, 20)

 {

 Outlier();

 };

 };

 };

 };

 Last("Alternative Model 2: End Circular Bastion Palisade");

 };

 Phase("rectangular bastion palisade")

 {

 First("Alternative Model 2: Start Rectangular Bastion Palisade");

 Phase("rectangular bastion")

 {

 After("rectangular bastion post-mold")

 {

 R\_Date("UCIAMS-145761", 810, 20)

 {

 Outlier("General", 0.05);

 };

 R\_Date("UCIAMS-145762", 840, 20)

 {

 Outlier("General", 0.05);

 };

 };

 R\_Date("UCIAMS-145763: base of rectangular bastion trench", 805, 20)

 {

 Outlier("Charcoal", 1);

 };

 };

 R\_Date("UCIAMS-164694: burned area", 845, 20)

 {

 Outlier("General", 0.05);

 };

 };

 };

 };

 Boundary("Alternative Model 2: End Palisade");

 Difference("Alternative Model 2: Palisade Span", "Alternative Model 2: End Palisade", "Alternative Model 2: Start Palisade");

 };

 };