* BJPS REPLICATION MATERIALS
* Measuring the Costs of Privacy: A Look at the Distributional Effects of Private Bargaining
*
*

set more off
sort dispute respondentID partnerID year


* PART I
* Is there evidence of discrimination? (For TABLE 1)

* Model 1. How do complainants do across all outcomes?
xtreg imports_post i.complainant imports_tminus1 ln_gdp_resp ln_gdp_part dempair ln_total_imports, fe i(dispute_combined) cluster(dispute_combined)
margins complainant

* Test for RE or FE
xtreg imports_post i.complainant imports_tminus1 ln_gdp_resp ln_gdp_part dempair ln_total_imports if earlysettle == 1, fe i(dispute_combined)
est store fe
xtreg imports_post i.complainant imports_tminus1 ln_gdp_resp ln_gdp_part dempair ln_total_imports if earlysettle == 1, re
est store re
hausman fe re

* Model 2. How do complainants do when settling early?
xtreg imports_post i.complainant imports_tminus1 ln_gdp_resp ln_gdp_part dempair ln_total_imports if earlysettle == 1, fe i(dispute_combined) cluster(dispute_combined)
margins complainant

* Model 3. How do complainants do when going to a ruling?
xtreg imports_post i.complainant imports_tminus1 ln_gdp_resp ln_gdp_part dempair ln_total_imports if outcome == 3, fe i(dispute_combined) cluster(dispute_combined)
margins complainant


* PART II
* Do third parties play an enforcement role? (For TABLE 3)

* LR Test for whether instruments are a better fit: 
heckman imports_post = lnthird ln_gdp_resp ln_gdp_part imports_tminus1 dempair ln_total_imports if nonparticipant == 1 ,  select(noruling = ln_gdp_part ln_gdp_resp imports_tminus1 ln_total_imports dempair claims_number lnthird)
est store H
heckman imports_post = lnthird ln_gdp_resp ln_gdp_part imports_tminus1 dempair ln_total_imports if nonparticipant == 1 ,  select(noruling = ln_gdp_part ln_gdp_resp imports_tminus1 ln_total_imports dempair lnthird)
est store R
lrtest H R 


* Model 4 (Count of third parties)
heckman imports_post = thirdparties ln_gdp_resp ln_gdp_part imports_tminus1 dempair ln_total_imports if nonparticipant == 1 , cluster(dispute_comb) select(early_v = ln_gdp_part ln_gdp_resp imports_tminus1 ln_total_imports dempair claims_number thirdparties)

* Model 5 (Dichotomous indicator of third parties)
heckman imports_post = thirdparties_dum ln_gdp_resp ln_gdp_part imports_tminus1 dempair ln_total_imports if nonparticipant == 1 , cluster(dispute_comb) select(early_v = ln_gdp_part ln_gdp_resp imports_tminus1 ln_total_imports dempair claims_number thirdparties_dum)

* Model 6 (Log of third parties)
heckman imports_post = lnthird ln_gdp_resp ln_gdp_part imports_tminus1 dempair ln_total_imports if nonparticipant == 1 , cluster(dispute_comb) select(early_v = ln_gdp_part ln_gdp_resp imports_tminus1 ln_total_imports dempair claims_number lnthird)

* Model 7 (Trade weighted count of third parties)
heckman imports_post = lntp_ave ln_gdp_resp ln_gdp_part imports_tminus1 dempair ln_total_imports if nonparticipant == 1 , cluster(dispute_comb) select(early_v = ln_gdp_part ln_gdp_resp imports_tminus1 ln_total_imports dempair claims_number lntp_ave)


* For TABLE 4
* Model 8 
heckman imports_post = thirdparties complainant ln_gdp_resp ln_gdp_part imports_tminus1 dempair ln_total_imports , cluster(dispute_comb) select(early_v = ln_gdp_part ln_gdp_resp imports_tminus1 ln_total_imports dempair claims_number thirdparties_dum)

* Model 9
heckman imports_post = thirdparties complainant comp_number ln_gdp_resp ln_gdp_part imports_tminus1 dempair ln_total_imports , cluster(dispute_comb) select(early_v = ln_gdp_part ln_gdp_resp imports_tminus1 ln_total_imports dempair claims_number thirdparties_dum)
margins, at(thirdparties = 1 complainant = 1 comp_number = 1)
margins, at(thirdparties = 1 complainant = 0 comp_number = 0)
margins, at(thirdparties = 10 complainant = 1 comp_number = 10)
margins, at(thirdparties = 10 complainant = 0 comp_number = 0)


* Additional
* Great powers:
xtreg imports_post i.complainant resp_gp imports_tminus1 ln_gdp_resp ln_gdp_part dempair ln_total_imports if earlysettle == 1, re i(dispute_combined) cluster(dispute_combined)
margins, at(complainant = 1 resp_gp = 0)
margins, at(complainant = 1 resp_gp = 1) 


*
* End. 10/22/2014