* ======================================================================
* Klüver/Spoon (BJPS): Who responds? Voters, parties and issue attention
* Replication Do File
* ======================================================================




clear
cd "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\"
use "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\KlüverSpoon_BJPS_Data.dta", clear


log using KlüverSpoon_BJPS_LogFile, replace



* ========
* Table 2
* ========


* Model 1
regress attent lag_attent lag_mip_all lag_pervote gov niche_party rile avg_sal_lag avgdm days, vce (cluster party_issue)

* Model 2
regress attent lag_attent lag_mip_all lag_pervote gov niche_party rile avg_sal_lag avgdm days lag_pervote_lag_mip_all gov_lag_mip_all niche_party_lag_mip_all, vce (cluster party_issue)

* Model 3
regress attent lag_attent lag_mip_all lag_pervote gov niche_party rile avg_sal_lag avgdm  days ///
lag_pervote_lag_mip_all gov_lag_mip_all niche_party_lag_mip_all rile_lag_mip_all avg_sal_lag_lag_mip_all avgdm_lag_mip_all days_lag_mip_all, vce (cluster party_issue)




* ========
* Table 3
* ========


* Model 4
regress attent lag_attent lag_mip_all lag_pervote gov rile avg_sal_lag avgdm days ///
green env_issue green_env env_issue_lag_mip_all green_lag_mip_all green_env_issue_lag_mip_all, vce (cluster party_issue)

* Model 5
regress attent lag_attent lag_mip_all lag_pervote gov rile avg_sal_lag avgdm days ///
green env_issue green_env env_issue_lag_mip_all green_lag_mip_all green_env_issue_lag_mip_all ///
lag_pervote_lag_mip_all gov_lag_mip_all rile_lag_mip_all avg_sal_lag_lag_mip_all avgdm_lag_mip_all days_lag_mip_all, vce (cluster party_issue)

* Model 6
regress attent lag_attent lag_mip_par lag_pervote gov rile avg_sal_lag avgdm days ///
green env_issue green_env env_issue_lag_mip_par green_lag_mip_par green_env_issue_lag_mip_par, vce (cluster party_issue)

* Model 7
regress attent lag_attent lag_mip_par lag_pervote gov rile avg_sal_lag avgdm days ///
green env_issue green_env env_issue_lag_mip_par green_lag_mip_par green_env_issue_lag_mip_par ///
lag_pervote_lag_mip_par gov_lag_mip_par rile_lag_mip_par avg_sal_lag_lag_mip_par avgdm_lag_mip_par days_lag_mip_par, vce (cluster party_issue)





* ===========
* Figure 1
* ===========


cd "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\"
use "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\KlüverSpoon_BJPS_Data.dta", clear


set more off


* Model
regress attent lag_mip_all lag_pervote lag_pervote_lag_mip_all  gov_lag_mip_all niche_party_lag_mip_all  gov niche_party  avg_sal_lag avgdm rile days  lag_attent, vce (cluster party_issue)

* Generate values for party size for which to calculate the marginal effects of voter issue attention 
gen MV = _n
replace MV=. if _n>30


* Grab elements of the coefficients and variance-covariance matrix
matrix b=e(b)
matrix V=e(V)

scalar b1=b[1,1]
scalar b3=b[1,3]
scalar b4=b[1,4]
scalar b5=b[1,5]


scalar varb1=V[1,1]
scalar varb3=V[3,3]
scalar varb4=V[4,4]
scalar varb5=V[5,5]


scalar covb1b3=V[1,3]
scalar covb1b4=V[1,4]
scalar covb1b5=V[1,5]

scalar list b1 b3 varb1 varb3 covb1b3

gen conbx = b1 + b3 * MV + b4*.3203845 + b5 * .1327593 if MV <= 30
gen consx = sqrt(varb1 + varb3*(MV^2) + 2*covb1b3*MV +  varb4*(.3203845^2)  + 2*covb1b4*.3203845 +  varb5*(.1327593^2) + 2*covb1b5* .1327593) if MV <= 30 


* Generate 90% confidence intervals
gen a = 1.645 *consx
gen upper = conbx + a
gen lower = conbx - a


* Computing the graph
#delimit ;
graph twoway line conb   MV, clwidth(medium) clcolor(blue) clcolor(black)
        ||   line upper  MV, clpattern(dash) clwidth(thin) clcolor(black)
        ||   line lower  MV, clpattern(dash) clwidth(thin) clcolor(black)
        ||   ,   

             legend(col(1) order(1 2) size(vsmall) label(1 "Marginal effect of voter issue attention as party size varies") 
                                      label(2 "90% Confidence Interval"))                            
			 yline(0, lcolor(black))
             xtitle("Party size", size(3)  )
             xsca(titlegap(2))
             ysca(titlegap(2))
			 xscale(r(-.902 3.3298))
             ytitle("Marginal effect of voter issue attention at t-1", size(3))
             scheme(lean2)  graphregion(fcolor(white)) ylabel(, nogrid) legend(position(6));
#delimit cr


keep if MV ~= .
keep  MV-lower

saveold "figure1.dta", replace




* =========
* Figure 2
* =========

cd "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\"
use "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\KlüverSpoon_BJPS_Data.dta", clear


set more off


* Model
regress attent lag_mip_all gov gov_lag_mip_all   lag_pervote_lag_mip_all niche_party_lag_mip_all lag_pervote niche_party   avg_sal_lag  avgdm rile days  lag_attent, vce (cluster party_issue)


* Grab elements of the coefficients and variance-covariance matrix
matrix b=e(b)
matrix V=e(V)

scalar b1=b[1,1]
scalar b3=b[1,3]
scalar b4=b[1,4]
scalar b5=b[1,5]


scalar varb1=V[1,1]
scalar varb3=V[3,3]
scalar varb4=V[4,4]
scalar varb5=V[5,5]


scalar covb1b3=V[1,3]
scalar covb1b4=V[1,4]
scalar covb1b5=V[1,5]


scalar list b1 b3 varb1 varb3 covb1b3

gen conbOpp = b1 + b3 * 0 + b4 *  13.71197 + b5 * .1327593
gen conbGov = b1 + b3 * 1 + b4 *  13.71197 + b5 * .1327593

gen conseOpp = sqrt(varb1 + varb3*(0^2) + 2*covb1b3*0 +  varb4*(13.71197 ^2)  + 2*covb1b4 * 13.71197  +  varb5*(.1327593^2) + 2*covb1b5* .1327593)
gen conseGov = sqrt(varb1 + varb3*(1^2) + 2*covb1b3*1 +  varb4*(13.71197 ^2)  + 2*covb1b4 * 13.71197  +  varb5*(.1327593^2) + 2*covb1b5* .1327593)


* Generate predicted values and confidence intervals
gen aOpp = 1.645*conseOpp
gen upperOpp = conbOpp + aOpp
gen lowerOpp = conbOpp - aOpp

gen aGov = 1.645*conseGov
gen upperGov = conbGov + aGov
gen lowerGov = conbGov - aGov


list conbOpp upperOpp lowerOpp if _n == 1		
list conbGov upperGov lowerGov if _n == 1		





* ==========
* Figure 3 
* ==========

cd "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\"
use "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\KlüverSpoon_BJPS_Data.dta", clear


regress attent lag_attent lag_mip_par lag_pervote gov  rile avg_sal_lag  avgdm days ///
green env_issue green_env env_issue_lag_mip_par green_lag_mip_par green_env_issue_lag_mip_par, vce (cluster party_issue)


matrix V=e(V)
svmat V, names(vvector)
outsheet vvector* using figure3_vvector.csv, comma replace

matrix b=e(b) 
svmat b, names(fixeff)
outsheet fixeff* using figure3_fixeff.csv, comma replace


drop if e(sample) == 0


keep attent lag_attent lag_mip_par lag_pervote gov  rile avg_sal_lag  avgdm days ///
green env_issue green_env env_issue_lag_mip_par green_lag_mip_par green_env_issue_lag_mip_par 


saveold figure3.dta, replace







* ==========
* Table A.1
* ==========

clear
cd "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\"
use "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\KlüverSpoon_BJPS_Data.dta", clear


sum attent lag_attent lag_mip_all lag_mip_par lag_pervote gov niche_party rile  avg_sal_lag avgdm days green env_issue





* ==========
* Table A.2
* ==========

clear
cd "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\"
use "C:\Users\ba9ze3-1\Dropbox\Dokumente\Papers\Party context paper\Paper # 3\Replication\KlüverSpoon_BJPS_Data.dta", clear



* Model 8
regress attent lag_attent lag_mip_par lag_pervote gov niche_party rile avg_sal_lag avgdm days, vce (cluster party_issue)

* Model 9
regress attent lag_attent lag_mip_par lag_pervote gov niche_party rile avg_sal_lag avgdm days lag_pervote_lag_mip_par gov_lag_mip_par niche_party_lag_mip_par, vce (cluster party_issue)

* Model 10
regress attent lag_attent lag_mip_par lag_pervote gov niche_party rile avg_sal_lag avgdm days  ///
lag_pervote_lag_mip_par gov_lag_mip_par niche_party_lag_mip_par rile_lag_mip_par avg_sal_lag_lag_mip_par avgdm_lag_mip_par days_lag_mip_par, vce (cluster party_issue)



log close