* ====================================================================================== *
* 	 A Two-Stage Theory of Discussant Influence on Vote Choice in Multi-Party Systems	 *	
*				--	Preparation of the dyadic data set (FINAL VERSION)  --				 *
*								JP, 2014-06-13											 *
* ====================================================================================== *

** Set working directory
	cd "$WD/BJPOLS_replication_files"
	
** Open respondent data file
	use rcs2009_ipk, clear
	set more off
	
** Create dyadic data file (wide format --> long format))
	reshape long ipk_bezGP ipk_bez1_GP ipk_bez2_GP ipk_bez3_GP ipk_bez4_GP ipk_bez5_GP	 ///
		ipk_bez6_GP	ipk_wisGP ipk_mverGP ipk_rl_corrGP wabsGP wabsEGO_GP wabsLA2EGO_GP	 ///
		panel_wabsEGO_GP panel_wabsEGO_d1_GP panel_wabsEGO_d2_GP panel_wabsEGO_d3_GP	 ///
		panel_wabsLA2EGO_d1_GP panel_wabsLA2EGO_d2_GP panel_wabsLA2EGO_d3_GP voteEGO_GP  ///
		voteLA2EGO_GP wabs_sonstige_GP agree_camp_GP agree_party_wcamp_GP 				 ///
		pos_agree_camp_GP pos_agree_party_wcamp_GP ipk_verGP, i(id) j(no)	
	
	tab(no), gen(GP)

* ====================================================================================== *
* Recoding
* ====================================================================================== *

** Vote intention discussant (dummies)
	tab wabsGP
	recode wabsGP (7/9=.), gen(voteGP) copy
	lab def vote_lb 1 "CDU/CSU" 2"SPD" 3"FDP" 4"Greens" 5"Left" 6"Other"
	lab val voteGP vote_lb
	label var voteGP "Vote intention of discussant"
	tab voteGP, gen(voteGPd)

** Agreement within dyads

* Cross-secion
	tab wabsEGO_GP wabsLA2EGO_GP
	gen agree_cs=.
	replace agree_cs= 3 if wabsEGO_GP==1 & wabsLA2EGO_GP==1
	replace agree_cs= 2 if wabsEGO_GP== 0 & wabsLA2EGO_GP==1
	replace agree_cs= 1 if wabsEGO_GP== 0 & wabsLA2EGO_GP==0
	replace agree_cs= 0 if pre005== 98
	lab var agree_cs "Agreement with discussant (cross-section)"
	lab def agree_lb 3 "Agreement on Party Choice" 2 "Agreement on Ideological Camp" 1 "Disagreement" 0 "Undecided"
	lab val agree_cs agree_lb
	tab agree_cs		
	recode agree_cs (0/2=1) (3=0), gen(disagree_party_undec)
	recode agree_cs (0/1=1) (2/3=0), gen(disagree_ideo_undec)
	recode agree_cs (1/2=1) (3=0) (0=0), gen(disagree_party)
	recode agree_cs (1=1) (2/3=0) (0=0), gen(disagree_ideo)
	recode agree_cs (3=1) (0/2=0), gen(agree_party)
	recode agree_cs (2/3=1) (0/1=0), gen(agree_ideo)
	recode agree_cs (0=1) (1/3=0), gen(undec)
		
* Panel
	tab voteEGO_GP voteLA2EGO_GP
	gen agree_pan=.
		replace agree_pan= 3 if voteEGO_GP==1 & voteLA2EGO_GP==1
		replace agree_pan= 2 if voteEGO_GP== 0 & voteLA2EGO_GP==1
		replace agree_pan= 1 if voteEGO_GP== 0 & voteLA2EGO_GP==0
	lab var agree_pan "Agreement with discussant (panel)"
	lab val agree_pan agree_lb
	tab agree_pan
	
** Rename agreement within camp var due to length limits
	gen agree_party_GP = agree_party_wcamp_GP 
	gen pos_agree_party_GP = pos_agree_party_wcamp_GP 

** Pre-election agreement (incl. undecided in the ref. cat.)
	gen ctr_agree_camp_GP = agree_camp_GP
	replace ctr_agree_camp_GP = 0 if wabsEGO== .a & voteGP<.
	tab ctr_agree_camp_GP
	
	gen ctr_agree_party_GP = agree_party_GP
	replace ctr_agree_party_GP = 0 if wabsEGO== .a & voteGP<.
	tab ctr_agree_party_GP	

	

** Missing if no / or no second discussant
	foreach var of varlist agree_camp_GP agree_party_GP											///
		pos_agree_camp_GP pos_agree_party_GP													///
		pos_agree_party_wcamp_GP agree_party_wcamp_GP											///
		ctr_agree_camp_GP																		///
		ctr_agree_party_GP																		///
		ipk_bezGP																				///
		ipk_wisGP																				///
		ipk_mverGP																				///
		ipk_verGP																				///
		ipk_rl_corrGP																			///
		GP1																						///
		pid_d pidLA2_d {
		replace `var'=.z if ipk_anz == 0
		replace `var'=.z if ipk_anz == 1 & GP1==0
		}

** Label variabels
	label var wabsEGO_GP "Agreement vote intention (party)"
	label var wabsLA2EGO_GP "Agreement vote intention (camp)"
	
	lab var agree_camp_GP "Same camp"
	lab var agree_party_wcamp_GP "Same party within camp"
	
	label var ipk_bezGP "Type of relationship"
	label var ipk_bez1_GP "- Spouse/life partner"
	label var ipk_bez2_GP "- Relative"
	label var ipk_bez3_GP "- Friend"
	label var ipk_bez4_GP "- Colleague"
	label var ipk_bez5_GP "- Neighbour"
	label var ipk_bez6_GP "- Other"
	
	label var ipk_tage "Frequency of discussions (1-7)"
	label var GP1 "First discussant (1= named first, 0= named second)"
	label var ipk_wisGP "Political expertise of discussant (0-3)" 
	label var ipk_mverGP "Trustworthiness of discussant (0-3)"
	label var ipk_verGP "Trustworthiness of discussant (0-3)"
	label var ipk_rl_corrGP "Response latency voting intention of the discussant"
	
	label var wabsEGOd2 "- SPD"
	label var wabsEGOd3 "- FDP"
	label var wabsEGOd4 "- Greens"
	label var wabsEGOd5 "- Left"
	
	label var voteGPd2 "- SPD"
	label var voteGPd3 "- FDP"
	label var voteGPd4 "- Greens"
	label var voteGPd5 "- Left"
	
	label var age "Age (in years)"
	label var male "Sex (1= male, 0= female)"
	label var abi "Education (1= baccalaureate, 0= lower)"
	label var polint3 "Interest in election outcome (0-4)"
	label var gkoal "Evaluation of Grand coalition (-5-+5)"		

* ====================================================================================== *
* Save dyadic data file		
* ====================================================================================== *
	save rcs2009_ipk_dyads, replace

exit