*BJPS replication dataset
*BEYOND PRESIDENTIALISM AND PARLIAMENTARISM
*JOSE ANTONIO CHEIBUB, ZACHARY ELKINS, TOM GINSBURG

*CODING THE REGIME VARIABLE

use /.../ceg_bjps_replication_tscs, clear

*CODE EXECUTIVE-LEGISLATIVE RELATIONS ELECTIVE ATTRIBUTES

gen emergency=0
recode emergency 0=1 if em==1

recode hosdec 1=1 else=0
recode hogdec 1=1 else=0
replace hogdec=hosdec if execnum==2
gen decree=0
replace decree=1 if hosdec==1 | hogdec==1

gen hosldiss=0
gen hogldiss=0
replace hosldiss=1 if legdiss==1 | legdiss==3
replace hogldiss=1 if legdiss==2 | legdiss==3 | legdiss==4
replace hogldiss=hosldiss if execnum==2
gen dissolve=0
replace dissolve=1 if hosldiss==1 | hogldiss==1

gen oversight=0
replace oversight=1 if (intexec>0 & intexec<4) | invexe==1

gen initiate=0
gen hosinit=0
gen hoginit=0
replace hosinit=1 if leg_in_1==1 
replace hoginit=1 if leg_in_2==1 | leg_in_3==1
replace hoginit=hosinit if execnum==2
replace initiate=1 if hosinit==1 | hoginit==1

gen veto=0
gen hosveto=0
gen hogveto=0
replace hosveto=1 if legapp==1 | legapp==4
replace hogveto=1 if legapp>1 & legapp<5
replace hogveto=hosveto if execnum==2
replace veto=1 if hosveto==1 | hogveto==1

gen cabapp=0
gen hoscab=0
gen hogcab=0
replace hoscab=1 if cabappt_1==1
replace hogcab=1 if cabappt_2==1
replace hogcab=hoscab if execnum==2
replace cabapp=1 if hoscab==1 | hogcab==1


*** FIGURE 1 ***
use /Users/cheibub/Dropbox/awork/chelkinsburg_bjps/ceg_bjps_replication_tscs, clear
gen pres=1 if regime==1
recode pres missing=0
gen parl=1 if regime==2
recode parl missing=0
gen semi=1 if regime==3
recode semi missing=0
tab regime pres
tab regime parl
tab regime semi
foreach x of varlist pres parl semi {
egen mn`x'=mean(`x'), by(year)
egen total`x'=total(`x'), by(year)
}
set scheme s1mono
line totalpres totalparl totalsemi year if year>1920 & year<2007, legend(off) ///
	title("Figure 1: Number of Constitutions by Government Type", size(small)) ///
	ytitle("Number of Constitutions") ///
	xtitle("Year") ///
	text(21 1930 "Presidentialism") text(14 1960 "Parliamentarism") text(17 1990 "Semi-presidentialism") ///
	sort


use /.../ceg_bjps_replication_401, clear

*INTERCORRELATION AMONG REGIME VARIALBLES
tab regime no_ce
tab regime dpi_system
tab no_ce dpi_system
tab no_ce hinst
tab dpi_system hinst

*TABLE 2
table regime if year<1945, c(n year m veto m decree m emergency m dissolve )
table regime if year<1945, c(n year m oversight m initiate m cabapp )

table regime if year>1944, c(n year m veto m decree m emergency m dissolve )
table regime if year>1944, c(n year m oversight m initiate m cabapp )

sum veto decree emergency initiate oversight cabapp if year<1945&regime~=.
sum veto decree emergency initiate oversight cabapp if year>1944&regime~=.

*CREATING SIMILARIY MEASURES
gen c="c"
gen b="b"
gen a="a"
gen d="d"
gen e="e"

egen cowcode_year=concat(cowcode year), punct(_)
egen c_cowcode_year=concat(c cowcode year), punct(_)
egen b_cowcode_year=concat(b cowcode year), punct(_)
egen a_cowcode_year=concat(a cowcode year), punct(_)
egen d_cowcode_year=concat(d cowcode year), punct(_)
egen e_cowcode_year=concat(e cowcode year), punct(_)

matrix diss a= hogdec hogem hogldiss oversight hoginit hogveto hogcab, names(a_cowcode_year) match proportion /*just head of govt*/
matrix diss b= decree emergency dissolve oversight initiate veto cabapp, names(b_cowcode_year) match proportion /*exec as monolith*/
matrix diss c= hogdec hosdec hogem hosem hogldiss hosldiss oversigh hoginit hosinit hogveto hosveto hoscab hogcab, names(c_cowcode_year) match proportion /*treating as separate offices*/
matrix diss d= decree emergency oversight initiate veto cabapp, names(d_cowcode_year) match proportion /*without dissolve exec as monolith*/
matrix diss e= decree emergency oversight initiate veto cabapp amnd pardon execimm bicam immunity budpro, names(e_cowcode_year) match proportion /*without dissolve plus other electives; exec as monolith*/

svmat a, names(col)
svmat b, names(col)
svmat c, names(col)
svmat d, names(col)
svmat e, names(col)
drop  c_cowcode_year a_cowcode_year b_cowcode_year d_cowcode_year e_cowcode_year

keep c_* b_* a_* d_* e_* cowcode_year system_num region regtype regtype_ze regime hinst latest

reshape long c_ b_ a_ d_ e_, i(cowcode_year) j(cowcode_yearb) string

rename c_ simsplit
rename a_ simhog
rename b_ simmono
rename d_ simnodiss
rename e_ simextra

foreach x of varlist system_num region regtype regtype_ze regime hinst{
rename `x' `x'a
}
egen yearb=ends(cowcode_yearb), tail punct(_)
egen cowcodeb=ends(cowcode_yearb), head punct(_)
egen yeara=ends(cowcode_year), tail punct(_)
egen cowcodea=ends(cowcode_year), head punct(_)
destring cowcodea cowcodeb yeara yearb, force replace


use /.../ceg_bjps_replication_similarity, clear

*TABLE 3
sum simnodiss
sum simnodiss if bothpres_r==1 
sum simnodiss if bothparl_r==1
sum simnodiss if bothsemi_r==1
sum simnodiss if presparl_r==1
sum simnodiss if pressemi_r==1
sum simnodiss if parlsemi_r==1

*TABLE 4
gen yeardiff_b=yeardiff*100
sum yeard*
regress simnodiss samecoun yeardiff samesysr samereg
regress simnodiss samecoun yeardiff samesysr samereg if postwar==0
regress simnodiss samecoun yeardiff samesysr samereg if postwar==1

regress simnodiss samecoun yeardiff samereg bothpres_r bothsemi_r bothparl_r
regress simnodiss samecoun yeardiff samereg bothpres_r bothsemi_r bothparl_r if postwar==0
regress simnodiss samecoun yeardiff samereg bothpres_r bothsemi_r bothparl_r if postwar==1


*TABLE 5
regress simnodiss samecoun yeardiff samesysh samereg if postwar==1
regress simnodiss samecoun yeardiff samereg bothpres_h bothsemi_h bothparl_h if postwar==1
regress simnodiss samecoun yeardiff samereg samesysh if yeara>1973&yearb>1973
regress simnodiss samecoun yeardiff samereg bothpres_h bothsemi_h bothparl_h if yeara>1973&yearb>1973
regress simnodiss samecoun yeardiff samereg samesysh if yeara>1989&yearb>1989
regress simnodiss samecoun yeardiff samereg bothpres_h bothsemi_h bothparl_h if yeara>1989&yearb>1989


*ROBUSTNESS CHECKS
*diff measures of dv
regress simmono samecoun yeardiff samereg samesysr 
regress simsplit samecoun yeardiff samereg samesysr 
regress simhog samecoun yeardiff samereg samesysr 
regress simnodiss samecoun yeardiff samereg samesysr