!For a detailed overview of MNLFA code and additional example scripts, see
!supplemental info provided by Bauer et al. (2017) at the link provided below.
!http://supp.apa.org/psycarticles/supplemental/met0000077/MET_Bauer_2015-0386R2_Supp[1].pdf
!Bauer, D.J. (2016). A more general model for testing measurement invariance and differential item
!functioning. Psychological Methods. 

Data: 
file is /MNLFA_CUmeasure.dat;


Define:
Agecent = age2 - 9.54;

variable: names are
subjectkey 
prosocial_q1_p prosocial_q2_p prosocial_q3_p cbcl_q26_p 
age2 demo_sex_v2 
demo_ethn_v2 demo_race_a_p___10 demo_race_a_p___11 
demo_race_combinedother
abcd_site rel_family_id;

Usevariables are
prosocial_q1_p prosocial_q2_p prosocial_q3_p cbcl_q26_p
demo_sex_v2
demo_ethn_v2 demo_race_a_p___11 
demo_race_combinedother
Agecent
;

Categorical are
prosocial_q1_p prosocial_q2_p prosocial_q3_p cbcl_q26_p;

Missing are all (-999);
IDvariable = id_s;

stratification = abcd_site;
CLUSTER = rel_family_id;

CONSTRAINT = 
demo_sex_v2
demo_ethn_v2 
demo_race_a_p___11 
demo_race_combinedother
Agecent;

ANALYSIS:
ESTIMATOR = MLR;
LINK = LOGIT;
TYPE=complex;
Processors = 16;

MODEL:
!Specify Model
CU by prosocial_q1_p* prosocial_q2_p* prosocial_q3_p* cbcl_q26_p*; 
[CU@0];!Set mean of latent factor to 0
CU (v_CU);! Specify label for factor variance

!Regress latent factor on covariates to examine moderation of latent factor mean
CU on demo_sex_v2 demo_ethn_v2 demo_race_a_p___11 demo_race_combinedother Agecent;

!Regressing item on covariates to to examine moderation of
!item intercept/threshold
prosocial_q3_p ON demo_race_a_p___11;

!!!!!Investigate Item DIF
CU BY prosocial_q1_p (L);

MODEL CONSTRAINT:
!Specify new parameters to investigate moderation of the factor variance and item factor loadings:

NEW (v_CU1*0 v_CU2*0 v_CU3*0 v_CU4*0 v_CU5*0 L0*0 L1*0);

!Investigate moderation of the factor variance and item factor loadings:
v_CU = EXP(v_CU1*demo_sex_v2 + v_CU2*demo_race_a_p___11 + v_CU3*demo_ethn_v2 + v_CU4*demo_race_combinedother + v_CU5*Agecent);

!Investigate moderation of item factor loadings:
L = L0 + L1*demo_race_combinedother;

Output: Sampstat;

SAVEDATA:
FILE IS /MAPscores.sav;
SAVE=FSCORES;