M.W. Tobler et al.

 Tapirs in French Guiana

**Estimates of density and sustainable harvest of the lowland tapir *Tapirus terrestris* in the Amazon of French Guiana using a Bayesian spatially explicit capture–recapture model**

Mathias W. Tobler, Fabrice Hibert, Laure Debeir and Cécile Richard-Hansen

WinBUGS model for multi-survey spatially explicit capture–recapture model, with survey, sex, and camera covariates and model selection.

model {

 #indicator variables for model selection

 for(i in 1:5)

 {

 w[i]~dbern(0.5)

 }

 for(t in 1:T){

 psi[t]~dunif(0, 1)

 }

 #sex ratio

 pi~dunif(0.1, 0.9)

 #base encounter rate

 alpha.lam~dnorm(0.0,0.10E-6)I(-15,15)

 #sex covariate

 beta.lam.sex[1]<-0 #reference class

 beta.lam.sex [2]~dnorm(0.0,0.10E-6)I(-15,15) #sex-specific lam0

 #session covariate

 for(t in 2:T){

 beta.lam.t[t]~dnorm(0.0,0.10E-6)I(-15,15)

 }

 beta.lam.t[1]<-0

 #camera covariate

 for(g in 2:G)

 {

 beta.lam.cam[g]~dnorm(0.0,0.10E-6)I(-15,15) #encounter rate (g0)

 }

 beta.lam.cam [1]<-0 #reference class

 #sigma

 alpha.sig~dnorm(0.0,0.10E-6)I(-15,15) #adjust to your species

 beta.sig.sex[1]<-0

 beta.sig.sex[2]~dnorm(0.0,0.10E-6)I(-15,15)

 #session covariate

 for(t in 2:T){

 beta.sig.t[t]~dnorm(0.0,0.10E-6)I(-15,15)

 }

 beta.sig.t [1]<-0

 for(t in 1:T){ #loop over all years

 S[t]<-(xu[t]-xl[t])\*(yu[t]-yl[t]) #study area size

 for (i in 1:M){ #loop over all individuals

 sex[i,t]~dbern(pi)

 #sex[i,t]~dbin(pi[t],1)

 sex2[i,t]<-sex[i,t] + 1

 z[i,t]~dbern(psi[t]) #individual included or not

 SX[i,t]~dunif(xl[t], xu[t]) #individual activity center X

 SY[i,t]~dunif(yl[t], yu[t]) #individual activity center Y

 log(sigma[i,t])<-alpha.sig + w[1]\*beta.sig.sex[sex2[i,t]]+w[2]\*beta.sig.t[t]

 sigma2[i,t]<-2\*sigma[i,t]\*sigma[i,t]

 for(j in 1:J) { #loop over all traps

 D2[i,j,t] <- pow(SX[i,t]-trapmat[j,1], 2) + pow(SY[i,t]-trapmat[j,2],2) #distance from camera to activity center

 log(lam0[i,j,t])<-alpha.lam + w[3]\*beta.lam.t[t] + w[4]\*beta.lam.cam[cam[j]] + w[5]\*beta.lam.sex[sex2[i,t]]

 Eo[i,j,t] <- lam0[i,j,t]\*exp(-D2[i,j,t]/sigma2[i,t]) #encounter rate at trap site

 log(pmean[i,j,t])<-log(K[j,t]) + log(Eo[i,j,t]) #encounter rate over all K occasions

 tmp[i,j,t]<-pmean[i,j,t]\*z[i,t] #if individual is not present (z=0) then probability is zero

 y[i,j,t]~dpois(tmp[i,j,t])

 }

 }

 }

 #calculate density

 for(t in 1:T){

 N[t]<-sum(z[1:M,t])

 D[t]<-N[t]/S[t]

 }

 #calculate maximum harvest based on estimated density

 rmax~dnorm(0.2,2500)

 Dmean<-mean(D[1:T])

 Pmax <- (exp(rmax)-1) \* 0.6 \* Dmean

 Hmax <- 0.2 \* Pmax

}